FOR mit 10 Variablen (will nicht)

[forumwurm]

hallo zusammen

hab mir eine FOR schlaufe zusammengebastelt, wenn ich diese im DOS prompt ausführe, dann funktionierts. wenn ich jedoch das script (test.cmd) starte mit diesem befehl, dann klappts nicht.

was mache ich falsch und könnte man das script auch schöner gestalten?

CALL FOR /F "eol=; tokens=1,2,3,4,5,6,7,8,9,10 delims=, " %i in ('Type Group2Add.csv') do @echo %i %j %k %l %m %n %o %p %q %r

Group2Add.csv Inhalt:
Wert1,Wert2, Wert3, Wert4, Wert5,Wert6,Wert7,Wert8, Wert9,Wert10
etc1,etc2,etc3,etc4,etc5,etc6,etc7,etc8,etc9,etc10
.....
usw.

gruss und dank, fw

[Tilo2300]

Innerhalb einer Batch-Datei mußt du %%i statt %i schreiben.

Und lass mal das CALL weg.
Mit CALL rufst du Unterroutinen oder externe Batch-Dateien auf, aber keine internen Befehle wie FOR.

[Tilo2300]

Batch-File:

cls
@echo off
FOR /F "eol=; tokens=1,2,3,4,5,6,7,8,9,10 delims=, " %%i in ('Type Group2Add.csv') do @echo %%i %%j %%k %%l %%m %%n %%o %%p %%q %%r
pause

Ausgabe der Kommandozeile:

Wert1 Wert2 Wert3 Wert4 Wert5 Wert6 Wert7 Wert8 Wert9 Wert10
etc1 etc2 etc3 etc4 etc5 etc6 etc7 etc8 etc9 etc10
Drücken Sie eine beliebige Taste . . .

[forumwurm]

ups, das CALL hat sich da fälschlicherweise reingeschlichen. das andere werde ich kurz testen, danke für die schnelle antwort.

Nachtrag: Jawohl, das hat funktioniert. besten dank.

[forumwurm]

noch eine andere frage zu FOR, hat mit dem Thema zwar nichts zu tun.

wie kann ich folgendes bewerkstelligen:

ich habe eine list.txt mit folgendem Inhalt

Albert1
test5
Zoo3
Berlin4
Stadt2


ich möchte nun eine batchdatei erstellen (test.cmd) welche die list.txt auslesen soll.

schlussentlich möchte ich per comandozeile folgendes eingeben:

test.cmd 4

und das resultat soll (zum testen) ein echo ausgeben

Berlin4

Hat da jemand gleich einen Rat.

Vielen Dank. fw

[Lengen1971]

Hi,

 setlocal EnableDelayedExpansion
cls
@echo off
SET CTN=0
FOR /F "eol=; tokens=1 delims= " %%i in (list.txt) do (
    IF !CTN! EQU %1% (
        @ECHO %%i
    ) 
    SET /A CTN=!CTN!+1    
)
pause 
  

%1 ist dabei der Übergabeparameter.
Du mußt aber mit EnableDelayedExpansion arbeiten, da der Batch-Interpreter bei der FOR-Schleife vor der Ausführung die %-Variablen mit den echten Werten ersetzt, somit wäre CTN immer 0.
Dann aber ! anstatt % verwenden.

Gruß
Michel

[Tilo2300]

Shalom!

Das geht aber auch ohne EnableDelayedExpansion:

@echo off
rem===============
rem welche zeile soll ausgelesen werden?
set zeile=4
rem aus welcher datei soll ausgelesen werden?
set datei=list.txt
rem===============

set cnt=0
for /f "tokens=*" %%i in (%datei%) do (
   set text=%%i
   call :suba
)
pause
goto :eof

:suba
   set /a cnt=%cnt%+1
   if not %cnt% == %zeile% goto :eof
   echo %text%
   goto :eof