Netzlaufwerke werden nicht immer verbunden

[Tilo2300]

Zu TO:

Bau dir doch einfach eine Abfrage rein in die cmd, in der Art
Ping Server -> Erreichbar dann weiter, ansonsten 10sec warten
und erneut abfragen.

Das könnte dann z. B. so gehen:

@echo off
:: --------------------------------------
set Zielserver=192.168.0.1
:: --------------------------------------


setlocal
set cnt=0
set FehlerCode=0

:Start
set /a cnt=%cnt%+1
cls
echo.
echo Pruefe Verfuegbarkeit des Servers ^(Versuch %cnt%^)...
ping -n 1 -w 1000 %Zielserver% >NUL
set FehlerCode=%errorlevel%
if %FehlerCode% GTR 0 (
   echo.
   echo Server ^[noch^] nicht erreichbar.
   echo Versuche es in 10 Sekunden noch einmal...
   call :wait10
)

if %FehlerCode% equ 0 (
   echo.
   echo Server gefunden.
   echo Verbinde Netzlaufwerke...
   call :connectLWs
   goto :Ende
)

if %cnt% GEQ 3 (
   echo.
   echo Der Server wurde nach %cnt% Versuchen nicht gefunden.
   echo Breche Verbindungsversuche ab.
   goto :Ende
)

goto :Start


:: -------------------------------------------------------------------
::                    SUBs
:: -------------------------------------------------------------------

:connectLWs
   :: hier 'net use'-Befehle eintragen (ECHOs nur zur Demo)
   echo net use X:
   echo net use Y:
   goto :EOF

:wait8
   echo.
   echo Warte einen Moment...
   echo ÚÄ¿ÚÄ¿
   For /L %%I in (1,1,6) Do (
      (Set /P i=Û) < NUL
      Ping 127.0.0.1 -n 2 > NUL
   )
   echo.
   echo.
   goto :EOF


:wait10
   echo ÚÄÄÄ¿ÚÄÄÄ¿
   For /L %%I in (1,1,10) Do (
      (Set /P i=Û) < NUL
      Ping 127.0.0.1 -n 2 > NUL
   )
   echo.
   echo.
   goto :EOF

:: -------------------------------------------------------------------
:ENDE
call :wait8
endlocal